图文并茂教你学会操作图数据库Neo4j

点击上方蓝色字体,选择“设为星标”

优质文章,及时送达

从上篇文章中我们了解到了什么是Neo4j、为什么要用Neo4j、什么场景使用 以及怎么安装,如果您还不想熟悉,点击此处,传送过去哦~

既然Neo4j是一个图数据库,那么毫无疑问,增删改查是必不可少的,这篇文章,我们就一起学习下Neo4j对节点以及关系的基本操作。

首先我们打开Neo4j的浏览器控制台(http://xxx.xxx.xxx.xxx:7474/browser),用户名是neo4j,默认密码也是 neo4j,如果你已经了密码,那么,就输入你修改的密码即可。登陆进去我们会看到如下的界面的,

没错,就是在大家最喜欢的美元符号那里输入 CQL语句的。这里我们拿学生和老师举例来说明。

一、增加节点

Neo4j使用的是create 命令进行增加,就类似与MySQL中的insert。

1.创建一个学生节点(只有节点,没有属性):

create (s:Student)

在美元符号输入完上面的CQL后,回车 或者 点击右侧的三角号执行按钮,会看到如下结果:

这说明我们已经创建完了学生节点。

不难看出 create 的语法如下:

create (<node-name>:<label-name>)
  • node-name:它是我们要创建的节点名称

  • label-name:它是我们要创建的标签名称

2.创建一个学生节点(创建具有属性的节点)

创建一个id为10000,名字为张三,年龄为18岁,性别为男的学生节点

create (s:Student{id:10000, name:"张三",age:18,sex:1}) 

执行后,会看到如下的结果:

这说明我们创建了一个具有id,name,age,sex四个属性的s节点。

不难理解,id、name、age、sex,就类似我们MySQL中 表中的字段一样。

创建带属性的节点语法如下:

create (<node-name>:<label-name> {
    <property1-name>:<property1-Value>,
    <property2-name>:<property2-Value>,
    ...,
    <property3-name>:<property3-Value>
})

property1-name就是属性名称,property1-Value就是属性值。

二、查询

我们在上一步创建了没有属性的节点和有属性的节点,那么问题来了,我们怎么查看呢?查询咯~

Neo4j使用的是match ... return ... 命令进行查询,就类似与MySQL中的select。

我们查询刚刚创建的节点信息。

1.全部查询学生

match (s:Student) return s

从上图可以看到我们刚刚创建的两个节点,一个是没有属性节点,一个是有属性的节点。两个节点是以图的形式展示,我们也可以切换左边的Graph(图)、Table(表格)、Text(文本)等来以不同的形式展示。

2.查询全部或者部分字段

只需要把要展示的字段以节点名 + 点号 + 属性字段 拼接即可,如下:

match (s:Student) return s.id,s.name,s.age,s.sex

这样就清楚的看到我们插入的学生属性信息。因为有一个是没有属性的节点,所以表格中第2行显示的各个值都是null。

3.查询满足年龄age等于18的学生信息

match (s:Student) where s.age=18 return s.id,s.name,s.age,s.sex

怎么样,这条件查询 是不是和MySQL的很相似。当然还有排序、分组、联合、分页等。为了能更好的演示这几种,我们先插入一部分数据,逐条插入:

create (s:Student{id:10001, name:"李四",age:18,sex:1}) return s
create (s:Student{id:10002, name:"王五",age:19,sex:1}) return s
create (s:Student{id:10003, name:"赵六",age:20,sex:1}) return s
create (s:Student{id:10004, name:"周七",age:17,sex:0}) return s
create (s:Student{id:10005, name:"孙八",age:23,sex:1}) return s
create (s:Student{id:10006, name:"吴九",age:15,sex:1}) return s
create (s:Student{id:10007, name:"郑十",age:19,sex:0}) return s
create (s:Student{id:10008, name:"徐十一",age:18,sex:1}) return s
create (s:Student{id:10009, name:"朱十二",age:21,sex:1}) return s
create (s:Student{id:10010, name:"谭十三",age:22,sex:1}) return s

这个我们在create 的语句后面加上了return,意思就是我插入完你要把数据返回给我看下,如下:

这样,我们的数据就造好了,我们可以先查询全部的看下:

match (s:Student) return s.id,s.name,s.age,s.sex

上图的左下角我们可以看到一共有12条数据。一条没有属性的 + 11条有属性的。

4.查询出所有的男生(sex=1)并按年龄倒叙排序

match (s:Student) where s.sex=1 return s.id,s.name,s.age,s.sex order by s.age desc

很清晰,是以age倒叙排序的。

5.查询出名字不为null,且按性别分组

这里要注意一点,CQL中的分组和SQL是有所差异的,在CQL中不用显式的写group by分组字段,由解释器自动决定:即未加聚合函数的字段自动决定为分组字段。

match (s:Student) where s.name is not null return s.sex,count(*)

不难看出,上面是按sex字段分组的。

6.union联合查询(查询性别为男或者女的,且年龄为19岁的学生)

match (s:Student) where s.sex=1 and s.age=19 return s.id,s.name,s.sex,s.age
union 
match (s:Student) where s.sex=0 and s.age=19 return s.id,s.name,s.sex,s.age

有union,当然也有 union all,这两个的区别和SQL中也是一样的。

  • union:对两个结果集进行并集操作,不包括重复行;

  • union all:对两个结果集进行并集操作,包括重复行;

7.分页查询(每页4条,查询第3页的数据)

match (s:Student) return s.id,s.name,s.sex,s.age skip 8 limit 4

上面CQL中的skip表示跳过多少条,limit表示获取多少条。每页4条,查询第三页的数据,也就是跳过前8条,查询4条,或者说从第8条开始,不包括第8条,然后再查询4条。

8.in操作(查询id为10001和10005的两个数据)

match (s:Student) where s.id in [10001,10005] return s.id,s.name,s.sex,s.age

需要注意的是,这里 用的是中括号,和SQL中是有区别的。

三、增加关系

上面我们介绍了增加单个节点和查询的知识点。这里我们介绍下增加关系。为了存在关系,我们先创建一个老师节点。

创建一个教语文的年龄为35岁的男的王老师:

create (t:Teacher{id:20001,name:"王老师",age:35,sex:1,teach:"语文"}) return t

1.假设王老师所教的班级有3个学生:张三、李四、王五,这里我们就要创建王老师 和 3个学生的关系,注意,这里是为两个现有节点创建关系。

match (t:Teacher),(s:Student) where t.id=20001 and s.id=10000 
create (t)-[teach:Teach]->(s)
return t,teach,s

这样,王老师和张三的关系就创建了。下面,我们再继续创建王老师 和 李四、王五的关系。

match (t:Teacher),(s:Student) where t.id=20001 and s.id=10001 
create (t)-[teach:Teach]->(s)
return t,teach,s
match (t:Teacher),(s:Student) where t.id=20001 and s.id=10002 
create (t)-[teach:Teach]->(s)
return t,teach,s

不难发现,创建关系的语法如下:

match (<node1-label-name>:<node1-name>),(<node2-label-name>:<node2-name>) 
where <condition>
create (<node1-label-name>)-[<relationship-label-name>:<relationship-name>]
    ->(<node2-label-name>) 
或者
match (<node1-label-name>:<node1-name>),(<node2-label-name>:<node2-name>) 
where <condition>
create (<node1-label-name>)-[<relationship-label-name>:<relationship-name>
       {<relationship-properties>}]->(<node2-label-name>) 
  • node1-name表示节点名称,label1-name表示标签名称

  • relationship-name表示关系节点名称,relationship-label-name表示关系标签名称

  • node2-name表示节点名称,label2-name表示标签名称

老师和学生的关系增加了,我们查询下:

match (t:Teacher)-[teach:Teach]-(s:Student) return t,teach,s

这关系就很显然了吧。王老师教张三、李四、王五。

2.我们给广东和深圳创建关系,深圳是属于广东省的。但是并没有广东省份节点和深圳市节点,没错,我们就是为两个不存在的节点创建关系。

create (c:City{id:30000,name:"深圳市"})-[belongto:BelongTo{type:"属于"}]->(p:Province{id:40000,name:"广东省"})

我们查询下我们创建的深圳和广东的关系。

match (c:City{id:30000,name:"深圳市"})-[belongto:BelongTo{type:"属于"}]->(p:Province{id:40000,name:"广东省"}) return c,belongto,p

为两个不存在的节点创建关系的语法如下:

create (<node1-name>:<label1-name>
    {<property1-name>:<property1-Value>,
    <property1-name>:<property1-Value>})-
[(<relationship-name>:<relationship-label-name>{<property-name>:<property-Value>})]
->(<node2-name>:<label2-name>
    {<property1-name>:<property1-Value>,
    <property1-name>:<property1-Value>})

当然,属性都非必填的,只是为了更加准确。

如果我们要查询Neo4j中全部的关系需要怎么写CQL呢,如下:

match (a)-[b]-(c) return a,b,c

三、修改

Neo4j中的修改也和SQL中的是很相似的,都是用set子句。和es一样,Neo4j CQL set子句也可以向现有节点或关系添加新属性。

通过上面的查询,我们已经熟记了学生张三的年龄是18岁,2020年了,张三也长大了一岁,所以我们就需要把张三的年龄改为19。

match (s:Student) where s.name="张三" set s.age=19 return s

从上图的红色框中我们可以清晰的看到张三的年龄已经更新到19了。

四、删除

Neo4j中的删除也和SQL中的是很相似的,都是delete,当然,除了delete删除,还有remove删除。

1.删除单个节点

这里以删除学生节点中没有属性的来举例:

先查询下学生中没有属性的节点

match (s:Student) where s.name is null return s

然后我们再删除这个节点:

match (s:Student) where s.name is null delete s

把上面查询的CQL中的return 改为 delete 就OK了。

执行完上面的删除CQL后,我们再重新查询下:

发现已经不存在没有属性的学生节点了,这说明我们已经删除成功了。

2.删除带关系的节点

这里我们以删除广东和深圳的关系来举例:

match (c:City{id:30000,name:"深圳市"})-[belongto]->(p:Province{id:40000,name:"广东省"}) return c,belongto,p

这个时候是有数据的。

然后我们执行下面的删除CQL,把上面的查询CQL中的return 改为 delete哦:

match (c:City{id:30000,name:"深圳市"})-[belongto]->(p:Province{id:40000,name:"广东省"}) delete c,belongto,p

执行完上面的删除CQL后我,我们重新再查询下:

发现已经不存在广东和深圳这两个节点以及关系了。

3.删除全部节点已经关系

这里这个CQL主要用作测试的,生产环境可不要执行,否则,真的是从删库到跑路了~

match (n) detach delete n

这个CQL就不演示了。

4.删除节点或关系的现有属性

可以通过remove来删除节点或关系的现有属性。

例如,我们删除学生李四节点中的sex属性:

match (s:Student{id:10001}) remove s.sex

执行完上面的remove CQL后,我们重新查询下:

看到李四的sex属性为null了。

五、总结

这篇文章就介绍了下Neo4j中的CQL,以及增删改查,我们也在实践中和MySQL中的某些SQL做了对比。下篇文章继续介绍,neo4j在springboot中的应用。

 

相关推荐
©️2020 CSDN 皮肤主题: Age of Ai 设计师:meimeiellie 返回首页